MacWorld 1999 July/Macworld (1999-07).dmg/Shareware World/Graphics/Popup Xtra 3.2/popdemo.dir/00003_Script_Popup navigation behavior

Text File | 1999-04-10 | 1KB | 50 lines

-- Popup navigation behavior
--
-- Purpose: Puts the names of all of the movie's markers
-- into a Popup menu at runtime. Checks a specified field
-- for user's frame choice and goes to that frame.
--
-- Usage: Place on all frames where you want to loop in the
-- same frame until the user makes a menu choice to go
-- elsewhere
--
-- Requires: A field to hold the user's choice. The field does
-- not have to be on stage.
--

property nextFrameField,frameLabelsField,popupMenuName

on beginSprite me
  put the labelList into field frameLabelsField
  refreshMenu(member popupMenuName)
end

on exitFrame me
  if field nextFrameField <> "" then
    go field nextFrameField
    put "" into field nextFrameField
  else
    go the frame
  end if
end

on getPropertyDescriptionList  me
  set p_list = [:]
  set temp = [:]
  addProp temp,#comment,"Name of Popup menu to use for navigation"
  addProp temp,#format,#string
  addProp temp,#default,"Navigation menu"
  addProp p_list,#popupMenuName,temp
  set temp = [:]
  addProp temp,#comment,"Field name of Popup menu contents field"
  addProp temp,#format,#string
  addProp temp,#default,"Labels list"
  addProp p_list,#frameLabelsField,temp
  set temp = [:]
  addProp temp,#comment,"Field name containing next frame to go to"
  addProp temp,#format,#string
  addProp temp,#default,"Next frame"
  addProp p_list,#nextFrameField,temp
  set temp = [:]
  return p_list
end